package rw
{
    import flare.vis.data.DataSprite;
    import flare.vis.data.render.IRenderer;
    
    import flash.display.Graphics;

    public class PeopleRenderer implements IRenderer
    {
        public function PeopleRenderer() { }
        
        public function render(d:DataSprite):void
        {
            var lineAlpha:Number = d.lineAlpha;
            var fillAlpha:Number = d.fillAlpha;
            
            var g:Graphics = d.graphics;
            g.clear();
            if (d.props['highlight']) {
                var splitHeight:Number = d.h * d.data.deathsMale / d.size;
                
                if (fillAlpha > 0) g.beginFill(0x007BA7, fillAlpha);
                g.drawRect(d.u-d.x, d.v-d.y, d.w, splitHeight);
                
                if (fillAlpha > 0) g.beginFill(0xFB607F, fillAlpha);
                g.drawRect(d.u-d.x, d.v-d.y + splitHeight, d.w, d.h - splitHeight);
            } else {
                if (fillAlpha > 0) g.beginFill(d.fillColor, fillAlpha);
                if (lineAlpha > 0) g.lineStyle(d.lineWidth, d.lineColor, lineAlpha);
                
                g.drawRect(d.u-d.x, d.v-d.y, d.w, d.h);
            }
        }
        
    }
}